//W:Mute 2004 - Abstract
//www.wmute.org
// Game of life extended to 2.5 dimensions. A variable interaction between several layers is included.

int xsiz=100;
int ysiz=40;
int zsiz=20;
int hxsiz=xsiz/2;
int hzsiz=zsiz/2;
float cores=0.2f;
int interaction=2;
int range=4;
int comeAlive = 3;
int belongDead = 4;
float oCores=cores;
int oInteraction=interaction;
int oRange=range;
int oComeAlive=comeAlive;
int oBelongDead=belongDead;
int blur=180;
boolean changed=false;
boolean textOn=true;
boolean resetCalled=false;
boolean noise=false;
int currentSites[] = new int[xsiz*ysiz*zsiz];
int newSites[] = new int[xsiz*ysiz*zsiz];
int indices[][][]=new int[xsiz][ysiz][zsiz];
float ax[]=new float[xsiz*ysiz*zsiz];
float ay[]=new float[xsiz*ysiz*zsiz];
int w=400;
int output[] = new int[640*360];
BFont fontA;
float sscale = w/50;
float csize;
int index=0;

HScrollbar hs1,hs2,hs3,hs4,hs5,hs6;

void setup()
{ 
  size(640,360);
  fontA = loadFont("Futura-Medium.vlw.gz");
  textFont(fontA,18);
  framerate(30);
  colorMode(HSB);
  hs1 = new HScrollbar(450, 70, 180, 10, 1,50);
  hs2 = new HScrollbar(450, 120, 180, 10,1,72);
  hs3 = new HScrollbar(450, 170, 180, 10,1,120);
  hs4 = new HScrollbar(450, 220, 180, 10,1,60);
  hs5 = new HScrollbar(450, 270, 180, 10,1,40);
  hs6 = new HScrollbar(450, 320, 180, 10,1,60);
  background(40,58,255);
  noStroke();
  for (int i=0; i<xsiz; i++) //Empty all sites
  {
    for (int j=0;j<ysiz;j++)
    {
      for (int k=0;k<zsiz;k++)
      {
        currentSites[index]=0;
        ax[index]=random(TWO_PI);
        ay[index]=random(PI);
        indices[i][j][k]=index;
        index++;
      }
    }
  }
  index=0;
  for(int i=0; i<640; i++) {
    for(int j=0; j<360; j++) {
      output[index] = color(00,0,255);
      index++;
    }
  }

  for (int dk=-range;dk<range+1;dk++)
  {
    for (int i=0; i<int(cores*xsiz*ysiz); i++) //Create growth cores
    {
      int ri=int(random(xsiz));
      int rj=int(random(ysiz));
      int rk=hzsiz+dk;
      currentSites[indices[ri][rj][rk]]=1;
    }
  }
}

void loop()
{
  background(0,0,255);
  cores=hs1.getPos()/360.0;
  interaction=int(hs2.getPos()/30.0);
  range=int(hs3.getPos()/30.0);
  comeAlive=1+int(hs4.getPos()/30.0);
  belongDead=3+int(hs5.getPos()/30.0);
  blur=int(hs6.getPos()*255.0/180.0);
  changed=((cores!=oCores)||(interaction!=oInteraction)||(range!=oRange)||(comeAlive!=oComeAlive)||(belongDead!=oBelongDead));
  oCores=cores;
  oInteraction=interaction;
  oRange=range;
  oComeAlive=comeAlive;
  oBelongDead=belongDead;

  if(changed||resetCalled) {
   reset();
   resetCalled=false;
  }
  
  index=0;
  for (int i=0; i<xsiz; i++)
  {
    for (int j=0; j<ysiz; j++)
    {
      for(int k=0; k<zsiz;k++)
      {
        int ui = i+1;
      if (ui==xsiz) {ui=0;};
        int uj = j+1;
      if (uj==ysiz) {uj=0;};
        int li = i-1;
      if (li==-1) {li=xsiz-1;};
        int lj = j-1;
      if (lj==-1) {lj=ysiz-1;};
        int lk = k-1;
      if (lk==-1) {lk=zsiz-1;};
        int uk = k+1;
      if (uk==zsiz) {uk=0;};
        int environment = currentSites[indices[ui][j][k]]+currentSites[indices[li][j][k]]+currentSites[indices[i][uj][k]]+currentSites[indices[i][lj][k]]+interaction*currentSites[indices[i][j][uk]]+interaction*currentSites[indices[i][j][lk]];
        environment += currentSites[indices[ui][uj][k]]+currentSites[indices[li][uj][k]]+currentSites[indices[li][uj][k]]+currentSites[indices[li][lj][k]];
      if ((currentSites[index]==0) && (environment ==comeAlive)) {newSites[index]=1;};
      if ((currentSites[index]==1) && ((environment < comeAlive)||(environment>belongDead))) {newSites[index]=0;};
      index++;
      }
    }
  }
  index=0;
  push();
  translate(100,20,100);
  rotateY(1.0);
  for (int i=0; i<xsiz; i++)
  {
    for (int j=0; j<ysiz; j++)
    {
      for(int k=0; k<zsiz;k++)
      {
        if (currentSites[index]>0)
        {
          csize=sscale / (1.0 + 0.5*abs(hzsiz - k));
          fill(141,119,120+20*abs(hzsiz - k),255-i*255/xsiz);
          push();
          translate(sscale*i, sscale*j, sscale*k);
          push();
          if (noise){
            rotateX(ax[index]);
            rotateY(ay[index]);
          };
          box(0.7*csize);
          pop();
          pop();
        }
        currentSites[index]=newSites[index];
        index++;
      }
    }
  }
  pop();
  index=0;
  for(int i=0; i<640; i++) {
    for(int j=0; j<360; j++) {
      pixels[index] = blend(pixels[index], output[index],blur) ;
      output[index] = pixels[index];
      index++;
    }
  }
  hs1.update();
  hs2.update();
  hs3.update();
  hs4.update();
  hs5.update();
  hs6.update();
  hs1.draw();
  hs2.draw();
  hs3.draw();
  hs4.draw();
  hs5.draw();
  hs6.draw();
  if (textOn)
  { 
    smooth();
    fill(141,119,100);
    stroke(141,119,100);
    text("Start: " + nf(cores,1,2),450, 60);
    text("Interaction: " + interaction,450, 110);
    text("Z-layers: " + range,450, 160);
    text("Come Alive: " + comeAlive,450, 210);
    text("Belong Dead: " + belongDead,450, 260);
    text("Blur: " + blur,450, 310);
    noStroke();
    noSmooth();
 } 

}

void keyPressed(){
  {
    if (key==' ')
    {
       textOn=!textOn;
    }
    else
    {
      if ((key=='n')||(key=='N')){
        noise=!noise;
      }
      else
      {
        resetCalled=true;
      }
    }
  }
}

int mix(int a,int b, int f)
{
  return a+(((b-a)*f)>>8);
}
int blend(int a, int b, int f)
{
  return mix(a>>16,b>>16,f)<<16 | mix(a>>8&0xff,b>>8&0xff,f)<<8 | mix(a&0xff,b&0xff,f);
}

void reset()
{
  index=0;
  for (int i=0; i<xsiz; i++) //Empty all
  {
    for (int j=0;j<ysiz;j++)
    {
      for (int k=0;k<zsiz;k++)
      {
        currentSites[index]=0;
        newSites[index]=0;
        ax[index]=random(TWO_PI);
        ay[index]=random(PI);
        index++;
      }
    }
  }
  for (int dk=-range;dk<range+1;dk++)
  {
    for (int i=0; i<int(cores*xsiz*ysiz); i++) //Create growth cores
    {
      int ri=int(random(xsiz));
      int rj=int(random(ysiz));
      int rk=hzsiz+dk;
      currentSites[indices[ri][rj][rk]]=1;
    }
  }
 }
 
 class HScrollbar
{
  int swidth, sheight;    // width and height of bar
  int xpos, ypos;         // x and y position of bar
  float spos, newspos;    // x position of slider
  int sposMin, sposMax;   // max and min values of slider
  int loose;              // how loose/heavy
  boolean over;           // is the mouse over the slider?
  boolean locked;
  float ratio;

  HScrollbar (int xp, int yp, int sw, int sh, int l,int sp) {
    swidth = sw;
    sheight = sh;
    int widthtoheight = sw - sh;
    ratio = (float)sw / (float)widthtoheight;
    xpos = xp;
    ypos = yp-sheight/2;
    spos = xpos + sp;
    newspos = spos;
    sposMin = xpos;
    sposMax = xpos + swidth - sheight;
    loose = l;
  }

  void update() {
    if(over()) {
      over = true;
    } else {
      over = false;
    }
    if(mousePressed && over) {
      locked = true;
    }
    if(!mousePressed) {
      locked = false;
    }
    if(locked) {
      newspos = constrain(mouseX-sheight/2, sposMin, sposMax);
    }
    if(abs(newspos - spos) > 1) {
      spos = spos + (newspos-spos)/loose;
    }
  }

  int constrain(int val, int minv, int maxv) {
    return min(max(val, minv), maxv);
  }

  boolean over() {
    if(mouseX > xpos && mouseX < xpos+swidth &&
    mouseY > ypos && mouseY < ypos+sheight) {
      return true;
    } else {
      return false;
    }
  }

  void draw() {
    fill(141,119,100,50);
    rect(xpos, ypos, swidth, sheight);
    if(over || locked) {
      fill(141,119,200);
    } else {
      fill(0,0, 102);
    }
    rect(spos, ypos, sheight, sheight);
  }

  float getPos() {
    // convert spos to be values between
    // 0 and the total width of the scrollbar
    return (spos-xpos) * ratio;
  }
}