import processing.opengl.*;

import toxi.geom.*;
import toxi.math.*;

int RESX=9;
int RESY=9;
int RESZ=50;

float noiseScaleX=10f/RESX;
float noiseScaleY=10f/RESY;
float noiseScaleZ=8f/RESZ;
int depth;

Grid grid;

void setup(){
  size(800,800,OPENGL);
  depth=width;
  background(255);
  hint(ENABLE_OPENGL_4X_SMOOTH);
  frameRate(20);
  grid = populateGrid();

}


void draw(){
  background(0);
  //pointLight(200,120,120, width/2,height/2,-800);
  pointLight(250,220,220, width/2,height/2,2*mouseY-1200);
  lights();
  translate(width/2,height/2,-depth);
  noStroke();
  
  grid.draw(0.9*width/(float)RESX,0.9*height/(float)RESY,4*depth/(float)RESZ,1.0f);
  grid = populateGrid();
 
}

Grid populateGrid(){
  Grid grid = new Grid(RESX,RESY,RESZ);
  int rmax =(int)random(5,25);
  //noiseSeed((long)random(2147483647));       
  for(int k=0;k<RESZ+1;k++){
    float offset = -frameCount;
    for(int i=0;i<RESX+1;i++){
      for(int j=0;j<RESY+1;j++){      
        grid.values[i][j][k]=dist(i,j,RESX/2f,RESY/2f)/8f+1.5*noise((i+0.01f*offset)*noiseScaleX,(j+0.01*offset)*noiseScaleY,(k+offset)*noiseScaleZ); 
        if((i==0)||(i==RESX)||(j==0)||(j==RESY)) grid.values[i][j][k]=2f;
        if((k==0)||(k==RESZ)) grid.values[i][j][k]=-2f;
        //grid.values[i][j][k]=2*noise(i*noiseScaleX,j*noiseScaleY,(k-frameCount)*noiseScaleZ)*j/(float)RESY; 
       
      }
    }
  }  
  return grid;
}



void keyPressed(){
  grid = populateGrid();
}

class Grid{
  float[][][] values;
  int RESX;
  int RESY;
  int RESZ;
  int HALFRESX;
  int HALFRESY;
  int HALFRESZ;

  Grid(int RESX, int RESY, int RESZ){
    values=new float[RESX+1][RESY+1][RESZ+1];
    this.RESX=RESX;
    this.RESY=RESY;
    this.RESZ=RESZ;
    this.HALFRESX=RESX/2;
    this.HALFRESY=RESY/2;
    this.HALFRESZ=RESZ/2;   
  }

  void draw(float sx, float sy, float sz,float tres){
    Cube cube;
    cube = new Cube();
    float v1,v2,v3,v4,v5,v6,v7,v8;
    //stroke(255,10);
    for(int k=0;k<RESZ;k++){
      fill(k*255/(float)RESZ,20);
    for(int i=0;i<RESX;i++){
      for(int j=0;j<RESY;j++){
           
          v1=values[i][j][k];
          v2=values[i+1][j][k];
          v3=values[i+1][j][k+1];
          v4=values[i][j][k+1];
          v5=values[i][j+1][k];
          v6=values[i+1][j+1][k];
          v7=values[i+1][j+1][k+1];
          v8=values[i][j+1][k+1];
          cube.set(v1,v2,v3,v4,v5,v6,v7,v8,(i-HALFRESX)*sx,(j-HALFRESY)*sy,(k-HALFRESZ)*sz,sx,sy,sz,tres);
          cube.draw(false);  
        }
      }
    }
  }

  Grid copy(){
    Grid result = new Grid (RESX,RESY,RESZ);
    for(int i=0;i<RESX+1;i++){
      for(int j=0;j<RESY+1;j++){
        for(int k=0;k<RESZ+1;k++){      
          result.values[i][j][k]=values[i][j][k];

        }
      }
    }
    return result;
  }
}