// Body in a box
// Humble beginnings of a "volume" library ?

 // Licensed under Creative Commons,  W:Blut 2009, Vanhoutte Frederik <www wblut com>
 // http://creativecommons.org/licenses/by/2.0/be/deed.en
 //
 // Disclaimer: the software
 //
 // This Processing sketch is free code and provided without any warranty.
 // It is free for any use. It represents some amateur coding by the author.
 // It is not intended to have any instructional value nor does it represent good coding practice. 



int numPoints=20; //number of points in the container
int currentSelection=0;
// simple arrays to store the properties of the points
PVector[] points=new PVector[numPoints];// 
PVector[] vels=new PVector[numPoints];

// coordinates of the containervertices
float[][] containerVertices;
// simple face array for the container. Each subarray contains the indices of the vertices.
int[][] containerFaces;

float bufferMouseX, bufferMouseY;

//half-edge mesh, one for each voronoi cell
HE_Mesh[] voronoiCells=new HE_Mesh[numPoints];

//representation of a plane, used to cut the mesh
Plane P=new Plane(new PVector(0,0,0),new PVector(0,1,0));

//size of box
int S=700;

void setup(){
  size(800,540,P3D);
  background(255);
  //smooth();
  //hint(ENABLE_OPENGL_4X_SMOOTH);
  initializePoints();
  buildContainer();
  buildVoronoi();
}

void draw(){
  drawVoronoiBox();
  updatePoints();
  buildVoronoi();
}

void initializePoints(){
    for (int i=0;i<numPoints;i++){
    points[i]=new PVector(random(-S,S),random(-S,S),random(-S,S));
    vels[i]=new PVector(random(-1,1),random(-1,1),random(-1,1));
    vels[i].normalize();
    vels[i].mult(2);
  } 
}


// container = cube, 8 vertices, 6 faces of 4 vertices each
void buildContainer(){
    float[][] tmpv={
    {S,S,S},
    {-S,S,S},
    {-S,S,-S},
    {S,S,-S},
    {S,-S,S},
    {-S,-S,S},
    {-S,-S,-S},
    {S,-S,-S}};
  containerVertices=tmpv;
  //  vertices need to be in a consistent order (clockwise, or counterclockwise around the face)
  int[][] tmpf={
    {0,1,2,3},
    {1,0,4,5},
    {0,3,7,4},
    {2,1,5,6},
    {5,4,7,6},
    {3,2,6,7}};
  containerFaces=tmpf;  
}


// A hack-n-slash approach to voronoi, literally. The individual cells are created by iteratively splitting
// the container mesh by the bisector planes of all other points. (Bisector plane = plane perpendicular to line
// between two points, positioned halfway between the points)

void buildVoronoi(){
  for (int i=0;i<numPoints;i++){
    voronoiCells[i]=new HE_Mesh();
    // each Voronoi cell starts as the entire container
    voronoiCells[i].buildMesh(containerVertices, containerFaces);
  }

  for (int i=0;i<numPoints;i++){
    for(int j=0;j<numPoints;j++){
      if(i!=j){
        PVector N=PVector.sub(points[j],points[i]); // plane normal=normalized vector pinting from point i to point j
        N.normalize();
        PVector O=PVector.add(points[j],points[i]); // plane origin=point halfway between point i and point j
        O.mult(0.5f);
        P=new Plane(O,N);
        voronoiCells[i].splitMesh(P,points[i]);
      }
    }
  }  
}

void drawVoronoiBox(){
    background(255);
  translate(width/2,height/2,0);
  bufferMouseX=0.95f*bufferMouseX+0.05f*mouseX;
  bufferMouseY=0.95f*bufferMouseY+0.05f*mouseY;
  rotateY(bufferMouseX/(float)width*TWO_PI);
  rotateX(bufferMouseY/(float)height*TWO_PI);
  noStroke();
  fill(200,0,0);
  voronoiCells[currentSelection].draw();// one cell is highlighted
  stroke(0,20);
  strokeWeight(2);
  noFill();
  for (int i=0;i<numPoints;i++){
    voronoiCells[i].drawEdges();
    voronoiCells[i].drawCurves();
  }
  
}

void updatePoints(){
  for (int i=0;i<numPoints;i++){
    points[i].add(vels[i]);
    if(points[i].x<-S){ 
      points[i].x=-2*S-points[i].x;
      vels[i].x*=-1;
    }
    if(points[i].y<-S){ 
      points[i].y=-2*S-points[i].y;
      vels[i].y*=-1;
    }
    if(points[i].z<-S){ 
      points[i].z=-2*S-points[i].z;
      vels[i].z*=-1;
    }
    if(points[i].x>S){ 
      points[i].x=2*S-points[i].x;
      vels[i].x*=-1;
    }
    if(points[i].y>S){ 
      points[i].y=2*S-points[i].y;
      vels[i].y*=-1;
    }
    if(points[i].z>S){ 
      points[i].z=2*S-points[i].z;
      vels[i].z*=-1;
    }
  }  
}


void mouseClicked(){
initializePoints();
  buildVoronoi();
}
void keyPressed(){
currentSelection++;
if(currentSelection==numPoints) currentSelection=0;

}