/*
// cyclic - a loop of tracking particles
 // 2008 Frederik Vanhoutte
 // http://www.wblut.com
 // Creative Commons, Attribution, Free for any use
 //
 //
 //
 // geomutils library by Karsten Schmidt
 // http://code.google.com/p/toxiclibs/downloads/list
 // http://toxi.co.uk/blog/
 */

import toxi.geom.*;
import toxi.math.*;

Tracker[] t;
int NUMTRACKERS=1000;

void setup(){
  size(800,800,P3D);
  background(255);


  // Create trackers
  // parameters
  // * random initial position
  // * random initial heading
  // * initial speed = 1.0
  // * maximum speed = 10.0
  // * maximum acceleration = 0.1
  // * maximum deceleration = 10.0
  // * random maximum turning angle 
  // * initial target = center of sketch

  t=new Tracker[NUMTRACKERS];
  for(int i=0;i<NUMTRACKERS;i++){
    t[i] = new Tracker(new Vec3D(random(-400,1200),random(-400,1200),0),Vec3D.randomVector(),1.0f,10.0f,0.1f,10.0f,PI/(1.0f+random(11.0f)),new Vec3D(400,400,0));
  }



}


void draw(){

  // Update and draw trackers
  // Target of each tracher is position of previous tracker.
  // Target of first tracher is position of last tracker to complete cycle.
  t[0].update(t[NUMTRACKERS-1].currentState.position);

  for(int i=1;i<NUMTRACKERS;i++){
    t[i].update(t[i-1].currentState.position);
  } 

  for(int i=1;i<NUMTRACKERS;i++){
    t[i].draw(); 
    // Smaal chance of resetting individual trackers to keep sketch dynamic
    if(random(1.0f)<0.00001f)  t[i] = new Tracker(new Vec3D(random(800),random(800),0),Vec3D.randomVector(),1.0f,10.0f,0.1f,10.0f,PI/(1.0f+random(11.0f)),new Vec3D(400,400,0));
  }
}

void mousePressed(){
  // Reset on mouseclick
  background(255);
  for(int i=0;i<NUMTRACKERS;i++){
    t[i] = new Tracker(new Vec3D(random(-400,1200),random(-400,1200),0),Vec3D.randomVector(),1.0f,10.0f,0.1f,10.0f,PI/(1.0f+random(11.0f)),new Vec3D(400,400,0));
  }

}