//W:Mute 2004 - Abstract
//www.wmute.org

int count;
int numsph;
spikey spheres[];
boolean updateFlag=false;
boolean firstClick=true;

void setup(){

  size(640,480);
  background(255);
  count=0;
  numsph=5;
  spheres = new spikey[numsph];
  reset();
}

void loop(){
  background(255);
  translate(320,240);
  for(int i=0;i<numsph;i++){
    if (updateFlag) spheres[i].update();
    spheres[i].draw();
  }
  count++;

}

void reset(){
  updateFlag=false;
  float shellThickness=200.0/(numsph+1);
  for(int i=0;i<numsph;i++){
    spheres[i]=new spikey((int)random(4,12),(int)random(20,60),random(50.0+i*shellThickness,(i+1)*shellThickness),random(-0.04,0.04),random(-0.04,0.04));
  }

}

void mouseReleased(){
  if (firstClick){
    firstClick=false;
  }
  else{
    reset();
  }
}

void keyPressed(){
  updateFlag=!updateFlag;
}

class spikey{
  memPoint points[][];
  int rows;
  int cols;
  int drawChance;
  float radius;
  float stepX, stepY;

  spikey(int ccols, int dC, float rr, float ssX, float ssY){
    cols=ccols;
    rows=cols+int(random(-3,+3));
    drawChance=dC;
    radius=rr;
    stepX=ssX;
    stepY=ssY;
    points=new memPoint[cols][rows];
    float theta, phi;
    for(int i=0;i<cols;i++){
      theta=TWO_PI/cols*i;
      for(int j=0;j<rows;j++){
        phi=-TWO_PI*(-cols*j+2.0*(rows-1)*i)/float(cols*(rows-1));
        points[i][j]= new memPoint(radius*cos(theta)*sin(phi),radius*sin(theta)*sin(phi),radius*cos(phi),(random(100.0)<drawChance));
      }
    }
  }

  void update(){
    float sax=sin(stepX);
    float cax=cos(stepX);
    float say=sin(stepY);
    float cay=cos(stepY);
    float cx,cy,cz,nx,ny,nz;
    for(int i=0;i<cols;i++){
      for(int j=0;j<rows;j++){
        cx=points[i][j].cx();
        cy=points[i][j].cy();
        cz=points[i][j].cz();
        nx=cx*cay+cy*sax*say+cz*cax*say;
        ny=cy*cax-cz*sax;
        nz=-cx*say+cy*sax*cay+cz*cax*cay;
        points[i][j].update(nx,ny,nz);
      }
    }

  }

  void draw(){
    for(int i=0;i<cols;i++){
      for(int j=0;j<rows;j++){
        if(points[i][j].visible){
          drawBox(i,j);
          drawArc(i,j);
        }
      }
    }
  }

  void drawBox(int i, int j ){
    int ia,fa,segs;
    segs=16;
    float ix,iy,iz,fx,fy,fz,dx,dy,dz;
    noStroke();
    push();
    translate(ix=points[i][j].px(),iy=points[i][j].py(),iz=points[i][j].pz());
    fill(120,ia=(int)max(min(120+points[i][j].pz(),200),0));
    box(5);
    translate(dx=0.2*points[i][j].cx(),dy=0.2*points[i][j].cy(),dz=0.2*points[i][j].cz());
    fill(183,160,160,fa=(int)max(min(80+1.2*points[i][j].cz(),200),0));
    box(3);
    pop();
    fx=ix+dx;
    fy=iy+dy;
    fz=iz+dz;
    drawLine(ix,iy,iz,fx,fy,fz,ia,fa,segs);
    push();
    translate(fx=0.6*points[i][j].ppx(),fy=0.6*points[i][j].ppy(),fz=0.6*points[i][j].ppz());
    fill(183,160,160,fa=(int)max(min(80+0.6*points[i][j].ppz(),200),0));
    box(2);
    pop();
    drawLine(ix,iy,iz,fx,fy,fz,ia,fa,segs);

  };

  void drawLine(float ix, float iy, float iz, float fx, float fy, float fz, int ia, int fa, int segs){
    float cx=ix;
    float cy=iy;
    float cz=iz;
    int ca=ia;
    float dx=(fx-ix)/segs;
    float dy=(fy-iy)/segs;
    float dz=(fz-iz)/segs;
    float da=float(fa-ia)/segs;
    beginShape(LINE_STRIP);
    for(int i=0;i<segs;i++){
      stroke(120,int(ia+=da));
      vertex(cx,cy,cz);
      cx+=dx;
      cy+=dy;
      cz+=dz;
    }
    endShape();

  }

  void drawArc(int i, int j){
    int a=(int)max(min(120+points[i][j].pz(),200),0);
    float da= float(a)/points[i][j].bufferL;
    beginShape(LINE_STRIP);
    for(int c=0;c<points[i][j].bufferL;c++){
      a=int(max(min(120+points[i][j].bufferZ[c],200),0)*(1-(float)c/points[i][j].bufferL));
      stroke(153,120,120,a);
      vertex(points[i][j].bufferX[c],points[i][j].bufferY[c],points[i][j].bufferZ[c]);

    }
    endShape();

  }

}

class memPoint{
  int bufferL;
  float bufferX[];
  float bufferY[];
  float bufferZ[];
  boolean visible;
  float slide;

  memPoint(float xx, float yy, float zz,boolean vv){
    bufferL=12;
    slide=0.1;
    bufferX=new float[bufferL];
    bufferY=new float[bufferL];
    bufferZ=new float[bufferL];
    for(int i=0;i<bufferL;i++){
      bufferX[i]=xx;
      bufferY[i]=yy;
      bufferZ[i]=zz;
    }
    visible=vv;
  }

  void update(float xx, float yy, float zz){
    for(int i=bufferL-1;i>0;i--){
      bufferX[i]+=slide*(bufferX[i-1]-bufferX[i]);
      bufferY[i]+=slide*(bufferY[i-1]-bufferY[i]);
      bufferZ[i]+=slide*(bufferZ[i-1]-bufferZ[i]);
    }
    bufferX[0]=xx;
    bufferY[0]=yy;
    bufferZ[0]=zz;
  }

float cx(){return bufferX[0];}
float px(){return bufferX[1];}
float ppx(){return bufferX[2];}
float cy(){return bufferY[0];}
float py(){return bufferY[1];}
float ppy(){return bufferY[2];}
float cz(){return bufferZ[0];}
float pz(){return bufferZ[1];}
float ppz(){return bufferZ[2];}
}