//W:Mute 2004 - Mobile
//www.wmute.org

int siz=300;
int nump=40;
Particle[] p = new Particle[nump];
Arc[] a= new Arc[nump];
float tfactor=1.0;
float dt=0.1;
float friction=0.01;
float mx=0;
float my=0;
boolean firstClick=true;

void setup(){
  size(800,800);
  background(255);
  noStroke();
  framerate(18);
  reset();
 }

void draw(){
  translate(100+siz-mx,100+siz-my);
  background(255);
  for(int i=0;i<nump;i++){
    fill(255,0,0,25);
    a[i].draw();
  }

  for(int i=0;i<nump;i++){
    p[i].fx=p[i].fy=p[i].fz=0;
  }
  for(int i=0;i<nump-1;i++){
    for(int j=i+1;j<nump;j++){
      float d=p[i].distance(p[j]);
      p[i].fx-=(p[i].x-p[j].x)/d;
      p[i].fy-=(p[i].y-p[j].y)/d;
      p[i].fz-=(p[i].z-p[j].z)/d;
      p[j].fx+=(p[i].x-p[j].x)/d;
      p[j].fy+=(p[i].y-p[j].y)/d;
      p[j].fz+=(p[i].z-p[j].z)/d;
    }
  }
  mx=0;
  my=0;

  for(int i=0;i<nump;i++){
    p[i].update();
    mx+=p[i].x;
    my+=p[i].y;
  }
  mx/=nump;
  my/=nump;
  for(int i=0;i<nump;i++){
    a[i].cx=mx;
    a[i].cy=my;
    a[i].r=p[i].distance(mx,my,0);
    a[i].sa=atan2(p[i].y-my,p[i].x-mx);
  }

  
  float v2max=0;
  for(int i=0;i<nump;i++){
    v2max=max(v2max,p[i].v2);
  }
  dt=tfactor*max(0.01,1.0/sqrt(v2max));

}

void mousePressed() 
{ 
  if(firstClick) { 
    firstClick=false; 
  } else { 
    reset(); 
  } 
} 

void reset() {
 for(int i=0;i<nump;i++){
    p[i]=new Particle(random(-siz,siz),random(-siz,siz),0,random(-1,1),random(-1,1),0,random(10));
    mx+=p[i].x;
    my+=p[i].y;
    }
  mx/=nump;
  my/=nump;
  for(int i=0;i<nump;i++){
    a[i]=new Arc(mx,my,p[i].distance(mx,my,0),atan2(p[i].y-my,p[i].x-mx),p[i].v()*HALF_PI,0.2,12);
  }
}


class Particle {
  float x,y,z,vx,vy,vz,v2,m,fx,fy,fz;

  Particle(float xx, float yy, float zz, float vxx, float vyy, float vzz,float mm) {
    m=mm;
    x=xx;
    y=yy;
    z=zz;
    vx=vxx;
    vy=vyy;
    vz=vzz;
    v2=vx*vx+vy*vy+vz*vz;
    fx=fy=fz=0;
  }

  void update(){
    vx+=dt*(fx-friction*vx)/m;
    vy+=dt*(fy-friction*vy)/m;
    vz+=dt*(fz-friction*vz)/m;
    v2=vx*vx+vy*vy+vz*vz;
    x+=dt*vx;
    y+=dt*vy;
    z+=dt*vz;
  }
  
  float v(){
   return sqrt(v2);
  }
  
  float distance(float qx, float qy, float qz){
    return dist(x,y,z,qx,qy,qz);
  }

  float distance(Particle q){
    return dist(x,y,z,q.x,q.y,q.z);
  }
}

class Arc {
  float cx,cy,r,sa,span,w;
  int segments;

  Arc(float xx, float yy, float rr, float aa,float ss,float ww, int segs){
    cx=xx;
    cy=yy;
    r=rr;
    sa=aa;
    span=ss;
    w=ww;
    segments=segs;
  }

  void draw(){
    float da=span/segments;
    float ca=sa;
    for(int i=0;i<segments;i++){
      triangle(cx+cos(ca)*r*(1-w),cy+sin(ca)*r*(1-w),cx+cos(ca)*r,cy+sin(ca)*r,cx+cos(ca+da)*r,cy+sin(ca+da)*r);
      triangle(cx+cos(ca)*r*(1-w),cy+sin(ca)*r*(1-w),cx+cos(ca+da)*r*(1-w),cy+sin(ca+da)*r*(1-w),cx+cos(ca+da)*r,cy+sin(ca+da)*r);
      ca+=da;
    }
    

  }

}