//W:Mute 2004 - Abstract
//www.wmute.org
//
//thread: http://processing.org/discourse/yabb/YaBB.cgi?board=Syntax;action=display;num=1096757051

ballSystem myBalls;
int nballs;
int runsPerFrame;

void setup()
{
  size(800, 500);
  framerate(30);
  nballs = 7;
  myBalls = new ballSystem(-150, 150,-150, 150,-150,150, -0.5, 0.5,-0.5, 0.5, -0.5,0.5,2.0,10.0,nballs);
  ellipseMode(CENTER_RADIUS);
  runsPerFrame=20;
}

void draw()
{
  background(127);
  push();
  translate(200,height/2,-100);
  rotateY(PI/4.0);
  for (int i=0; i<runsPerFrame; i++)
  {
    myBalls.run(i*255.0/runsPerFrame);
  }

  noFill();
  stroke(255);
  box(300);
  pop();
  myBalls.drawGrid();
}

class ballSystem{
  Ball[] myBalls;
  int nballs;
  float lowerX, upperX, lowerY, upperY, lowerZ, upperZ;
  float lowerVX, upperVX, lowerVY, upperVY, lowerVZ, upperVZ;
  float lowerRadius, upperRadius;
  color[][] grid;

  ballSystem(){
  }

  ballSystem(float lX, float uX, float lY, float uY, float lZ, float uZ,float lVX, float uVX, float lVY, float uVY, float lVZ, float uVZ, float lr, float ur, int nn){
    nballs=nn;
    lowerX=lX;
    upperX=uX;
    lowerY=lY;
    upperY=uY;
    lowerZ=lZ;
    upperZ=uZ;
    lowerVX=lVX;
    upperVX=uVX;
    lowerVY=lVY;
    upperVY=uVY;
    lowerVZ=lVZ;
    upperVZ=uVZ;
    lowerRadius=lr;
    upperRadius=ur;

    myBalls=new Ball[nballs*nballs];
    for(int i=0;i<nballs*nballs;i++){
      myBalls[i]=new Ball(random(lowerX,upperX),random(lowerY,upperY), random(lowerZ,upperZ), random(lowerVX,upperVX) ,random(lowerVY,upperVY), random(lowerVZ,upperVZ), random(lowerRadius,upperRadius));
    }
    grid=new color[nballs][nballs];
  }
  void run(float t){
    noStroke();
    for(int i=0;i<nballs*nballs;i++){
      grid[i%7][int(i/7)]=myBalls[i].run(t);
    }
    stroke(255,10);
    boundary();
    detectAndAdjust();
    //drawGrid();
  }

  void boundary(){
    float xi,yi,zi;
    for(int i=0;i<nballs*nballs;i++){
      xi=myBalls[i].x;
      yi=myBalls[i].y;
      zi=myBalls[i].z;
      if (xi < lowerX){
        myBalls[i].vx *= -1;
        myBalls[i].x=2*lowerX-xi;
      }
      if (yi < lowerY){
        myBalls[i].vy *= -1;
        myBalls[i].y=2*lowerY-yi;
      }
      if (zi < lowerZ){
        myBalls[i].vz *= -1;
        myBalls[i].z=2*lowerZ-zi;
      }
      if (xi > upperX){
        myBalls[i].vx *= -1;
        myBalls[i].x=2*upperX-xi;
      }
      if (yi > upperY){
        myBalls[i].vy *= -1;
        myBalls[i].y=2*upperY-yi;
      }
      if (zi > upperZ){
        myBalls[i].vz *= -1;
        myBalls[i].z=2*upperZ-zi;
      }
    }
  }

  void detectAndAdjust(){
    float xi,yi,zi,xj,yj,zj,vxi, vyi, vzi,vxj,vyj,vzj,mi, mj, mfactorii, mfactorjj,mfactorij,mfactorji,distfactor;
    for(int i=0;i<nballs*nballs;i++){
      xi=myBalls[i].x;
      yi=myBalls[i].y;
      zi=myBalls[i].z;
      for(int j=i+1;j<nballs*nballs;j++){
        xj=myBalls[j].x;
        yj=myBalls[j].y;
        zj=myBalls[j].z;
        distfactor=dist(xi,yi,zi,xj,yj,zj)/(myBalls[i].radius+myBalls[j].radius);
        if( distfactor<1.0 ){
          myBalls[i].age=0;
          myBalls[j].age=0;
          mi=1000.0*myBalls[i].radius*myBalls[i].radius*myBalls[i].radius;
          mj=1000.0*myBalls[j].radius*myBalls[j].radius*myBalls[j].radius;
          mfactorii=(mi-mj)/(mi+mj);
          mfactorjj=(mj-mi)/(mi+mj);
          mfactorij=(2.0*mj)/(mi+mj);
          mfactorji=(2.0*mi)/(mi+mj);
          vxi=myBalls[i].vx;
          vyi=myBalls[i].vy;
          vzi=myBalls[i].vz;
          vxj=myBalls[j].vx;
          vyj=myBalls[j].vy;
          vzj=myBalls[j].vz;
          myBalls[i].vx=mfactorii*vxi+mfactorij*vxj;
          myBalls[i].vy=mfactorii*vyi+mfactorij*vyj;
          myBalls[i].vz=mfactorii*vzi+mfactorij*vzj;
          myBalls[j].vx=mfactorji*vxi+mfactorjj*vxj;
          myBalls[j].vy=mfactorji*vyi+mfactorjj*vyj;
          myBalls[j].vz=mfactorji*vzi+mfactorjj*vzj;
          myBalls[i].x=xi-0.505*(xj-xi)/distfactor;
          myBalls[i].y=yi-0.505*(yj-yi)/distfactor;
          myBalls[i].z=zi-0.505*(zj-zi)/distfactor;
          myBalls[j].x=xj+0.505*(xj-xi)/distfactor;
          myBalls[j].y=yj+0.505*(yj-yi)/distfactor;
          myBalls[j].z=zj+0.505*(zj-zi)/distfactor;
        }
        if( distfactor<6.0 ){
          line(myBalls[i].x,myBalls[i].y,myBalls[i].z,myBalls[j].x,myBalls[j].y,myBalls[j].z);
        }
      }
    }
  }

  void drawGrid(){
    noStroke();
    for(int i=0;i<nballs;i++){
      for(int j=0;j<nballs;j++){
        fill(red(grid[i][j]),green(grid[i][j]),blue(grid[i][j]));
        rect(470+i*40,115+j*40,30,30);
      }
    }
  }

}

class Ball
{
  int bid;
  float x,y,z;
  float vx,vy,vz;
  float radius;
  int age;

  Ball(){
  }

  Ball(float xx, float yy, float zz, float vxx, float vyy, float vzz, float rr){
    x=xx;
    y=yy;
    z=zz;
    vx=vxx;
    vy=vyy;
    vz=vzz;
    radius=rr;
    age=0;
  }

  color run(float t)
  {
    fill(255,min(age/2,255),255,int(t/2));
    push();
    translate(0,0,z);
    ellipse(x, y, radius*(0.5+t/510), radius*(0.5+t/510));
    pop();
    x = x + vx;
    y = y + vy;
    z = z + vz;
    age++;
    return color(255,min(age/2,255),255,int(t/2));
  }

}